Раздел 12.7 - Ссылочные переменные: Подведение итогов

Чтобы помочь Вам разобраться в том, как эти, столь различные механизмы, "уживаются" друг с другом, мы создали пример пакета в котором они используются вместе. Сейчас Вам не обязательно понимать все мелкие нюансы этого примера, хотя у для этого у Вас уже вполне достаточно информации. При первом прочтении сосредоточтесь, чтобы увидеть картину в целом.

Разработанный нами пример - это настраиваемый пакет для создания стека, очень похожий на пример, который мы видели в разделе о настраиваемых модулях. Впрочем, теперь мы сможем использовать ссылочные типы для реализации неограниченного стека, и снять все ограничения на его размер. Поскольку мы хотим разрешить пользователям выполнять присваивание стеков, то будем использовать "Ada.Finalization", а сам тип Stack реализуем как потомок от типа Controlled, чтобы можно было управлять операциями финализации и присваивания (тип Controlled мы обсуждали в последнем разделе Урока 7).

Как и раньше, у нас будут операции помещения и извлечения из стека. Давайте еще добавим операцию "Empty" для очистки содержимого стека и булевскую функцию "Is_Empty", возвращающую True, если в стеке нет данных. Кроме того, добавим еще операцию "=", возвращающую True если два стека равны (два стека равны в том случае, если они имеют одинаковую длину и содержат одинаковые данные, размещенные в одинаковом порядке).

Рекомендуем Вам, при создании повторно используемых типов, добавлять еще и операцию "перемены мест" (swap) [Wheeler 1992]; заметим, что операция swap может быть реализована очень эффективно с использованием ссылочных типов. Наличие операции "Length" позволяет определить количество элементов в стеке. Кроме того, обратите внимание на новый тип - "Natural". Это предопределенный подтип типа Integer, начинающийся с нуля. Поскольку стек не может содержать отрицательное количество элементов, то логичнее было бы, чтобы функция Length возвращала величину типа Natural, а не Integer.

При реализации неограниченных типов необходимо всегда переопределять стандартные процедуры Adjust и Finalize. Если Вы этого не сделали, то, вероятнее всего, здесь что-то не так. Если бы мы не переопределили Adjust, присваивание привело бы к тому, что два "разных" стека ссылались бы на один и тот же элемент. В результате, если за этим последует финализация, то она затронет оба стека, а это не должно происходить. Если бы мы не переопределили операцию Finalize, то не выполнялось бы необходимое освобождение памяти для элементов.

Теперь, учитывая все выше сказанное, приведем спецификацию пакета Generic_Stack:

  with Ada.Finalization; use Ada.Finalization;

  generic
    type Item is private;  -- Данные, помещаемые в стек.

  package Generic_Stack is
    -- Пример реализации стека элементов Item.
    -- (C) 1996 David A. Wheeler.

    type Stack is new Controlled with private;
     -- Стековый тип. Присваивание копирует содержимое одного стека в другой,
     -- а также копирование каждого элемента.
     -- От типа Stack можно наследовать и перегружать операции, наследуемые от Controlled.
    type Stack_Access is access all Stack'Class;
     -- стандартный ссылочный тип.
    function "="(Left : in Stack; Right : in Stack) return Boolean;
     -- Стеки равны, если их длины равны и равны все их элементы соответственно.
    procedure Swap(Left : in out Stack; Right : in out Stack);
     -- Перемена местами содержимого двух стеков.

    procedure Push(S : in out Stack; I : in  Item);
    procedure Pop (S : in out Stack; I : out Item);
     -- Pop возбуждает Constraint_Error если Is_Empty(Stack).
    procedure Top (S : in out Stack; I : out Item);
     -- Top копирует, но не извлекает самый верхний элемент. 
     -- Top возбуждает Constraint_Error если Is_Empty(Stack).
    procedure Empty(S : in out Stack); -- Очистка данного стека

    function Is_Empty(S : in Stack) return Boolean; -- True если стек пуст.
    function Length(S : in Stack) return Natural; -- возвращает 0 если стек пуст

    -- Разрешается использование данного пакета любым способом
    -- при условии сохранении ссылки на автора (David A. Wheeler).
    -- NO WARRANTIES, EITHER EXPRESS OR IMPLIED, APPLY.

  private
    type Stack_Node;
    type Stack_Node_Access is access Stack_Node;
    type Stack is new Controlled with record
          Start : Stack_Node_Access;
        end record;
    procedure Adjust(Object : in out Stack);
    procedure Finalize(Object : in out Stack);
  end Generic_Stack;

Обратите внимание на ловкий трюк, который мы провернули: в пакете даже нет полного описания элемента! Поскольку элемент никуда не передается и никем не возвращается, то описание его типа можно оставить неполным, а завершить в теле настраиваемого пакета.

Так как пакет является настраиваемым, при использовании его необходимо конкретизировать каким-то типом. Для примера, конкретизируем его так, чтобы можно было помещать в стек величины типа Integer:

with Generic_Stack;
 -- Конкретизация стека целых величин.

package Stack_Int is new Generic_Stack(Integer);

И наконец, напишем короткую тестовую программу, демонстрирующую использование нашего настраиваемого стека:

with Stack_Int;
use  Stack_Int;

procedure Demo_GS is
 -- Пример использования пакета Generic_Stack
 -- на стеке целых величин.

 Stack1, Stack2 : Stack;
 Dummy : Integer;
begin
 Push(Stack1, 1); -- Помещаем 1 в Stack1.
 Push(Stack1, 2); -- Помещаем 2 в Stack1.
 Stack2 := Stack1; -- Копируем содержимое stack1 в stack2.
 Pop(Stack2, Dummy); -- Dummy теперь 2.
 Pop(Stack2, Dummy); -- Dummy теперь 1.
 --  Теперь Stack2 пуст а Stack1 содержит два элемента.
end Demo_GS;

В теле настраиваемого пакета содержатся операции, определенные в его спецификации и использующие ссылочные типы, о чем мы уже упоминали. Теперь можете спокойно переходить к изучению тела пакета Generic_Stack сопоставлять его со спецификацией, с примером конкретизации (создающим стек элементов типа Integer), другим примером конкретизации (создающим стек стеков элементов типа Integer), короткой демонстрационной программой и более длинной программой в которой стеки встречаются на каждом шагу.

Упражнение:

Могут ли пользователи пакета Generic_Stack, описанного выше, использовать тип Stack_Node_Access и манипулировать внутренней структурой стека?

1. Да
2. Нет

Перейти к предыдущему разделу	Перейти к следующему разделу	Вернуться к содержанию Урока 12

Исходная копия перевода размещена на сайте http://www.ada-ru.org